process apost

       Identification Division.
       Program-ID.    AR1234C.

       Environment Division.
       Input-output Section.
       File-control.
           Select InputFile  Assign to Database-AR1234F.
           Select PrintFile  Assign to Printer-QSysPrt.

       Data Division.
       File Section.
       FD  InputFile.
       01  InputRecord.
           copy dds-all-formats of AR1234F.
       FD  PrintFile.
       01  PrintRec        Pic X(132).

       Working-storage Section.

       01  End-of-file-switch Pic X    Value 'N'.
           88  End-of-file             Value 'Y'.
       01  ProperSpacing  Pic S9.
           88  Top-of-page             Value -1.
           88  SingleSpace             Value +1.
           88  DoubleSpace             Value +2.
       01  Edit1          Pic z,zzz,zzz.99-.
       01  Dashes         Pic x(20)
                          Value '===================='.
       01  PrintLine.
           05  Column01       Pic X(4)   Justified Right.
           05                 Pic X.
           05  Column02       Pic X(5)   Justified Right.
           05                 Pic X.
           05  Column03       Pic X(20).
           05                 Pic X.
           05  Column04       Pic X(5)   Justified Right.
           05                 Pic X.
           05  Column05       Pic X(18).
           05                 Pic X.
           05  Column06       Pic X(12)  Justified Right.
           05                 Pic X.
           05  Column07       Pic X(12)  Justified Right.
           05                 Pic X.
           05  Column08       Pic X(10).

       Procedure Division.
       Main-Logic.
           Perform 00-Initialize.
           Perform 10-Read.
           Perform 20-Process until End-of-File.
           Perform 30-Shutdown.
           Goback.

       00-Initialize.
           Open input InputFile.
           Open output PrintFile.
           Perform 40-PrintHeadings.

       10-Read.
           Read InputFile at end set End-of-file to True.

       20-Process.
           Move CompanyNo to Column01.
           Move CustomerNo to Column02.
           Move Sel0003-Data (1:Sel0003-Length) to Column03.
           Move RepNo to Column04.
           Move RepName to Column05.
           Move Balance to Edit1.
           Move Edit1 to Column06.
           Move PastDue to Edit1.
           Move Edit1 to Column07.
           Move LastPayDt to Column08.
           Perform 90-Write.
           Perform 10-Read.

       30-Shutdown.
           Close PrintFile.
           Close InputFile.

       40-PrintHeadings.
           Move 'Current Accounts Receivable' to PrintLine.
           Set Top-of-page to true.
           Perform 90-Write.

           Move 'Comp' to Column01.
           Move 'Acct' to Column02.
           Move 'Name' to Column03.
           Move 'Rep'  to Column04.
           Move 'Name' to Column05.
           Move 'Balance' to Column06.
           Move 'Overdue' to Column07.
           Move 'Last pay' to Column08.
           Set DoubleSpace to True.
           Perform 90-Write.

           Move Dashes to Column01, Column02, Column03,
                          Column04, Column05, Column06,
                          Column07, Column08.
           Perform 90-Write.

       90-Write.
           If not Top-of-page
              Write PrintRec from PrintLine after ProperSpacing
           else
              Write PrintRec from PrintLine after Page
           end-if.
           Move spaces to PrintLine.
           Set SingleSpace to True.