FQSYSPRT   O    F  132        PRINTER OFLIND(Overflow)
     F                                     PRTCTL(PrtCtlDS)

     D PrtCtlDS        DS            15
     D  pcSpacing              1     12
     D  pcSpcBefore            1      3
     D  pcSpcAfter             4      6
     D  pcSkpBefore            7      9
     D  pcSkpAfter            10     12
     D  pcLineNbr             13     15
     D
     D Overflow        S               N
     D SingleSpace     C                   CONST('001')
     D DoubleSpace     C                   CONST('002')
     D TopOfForm       C                   CONST('001')

     D PrintLine       DS           132
     D  Column01                      2
     D                                2
     D  Column02                    128

     D ActualFile      S             80A   VARYING
     D Command         S            250a
     D Option          S              2A
     D PageNbr         S              3P 0
     D SqlOK           C                   CONST('00000')

      /Copy Prototypes,QDMRTVFO

     C/Exec SQL
     C+   Declare Input cursor for
     C+      Select option,command From QAUOOPT
     C+      Order by option
     C/End-exec
     C                   EXSR      RtvOverride
     C                   EXSR      PrintHeaders
     C/Exec SQL
     C+   Open Input
     C/End-exec
     C                   IF        SqlStt <> SqlOK
     C                   EVAL      PrintLine = 'Open error; status '
     C                             + SqlStt + '.'
     C                   EXSR      Write
     C                   EXSR      Exit
     C                   ENDIF
     C
     C                   DOW       '1'
     C
     C/Exec SQL
     C+   Fetch Input into :Option,:Command
     C/End-exec
     C                   IF        SqlStt <> SqlOK
     C                   LEAVE
     C                   ENDIF
     C
     C                   IF        Overflow
     C                   EXSR      PrintHeaders
     C                   ENDIF
     C
     C                   EVAL      Column01 = Option
     C                   EVAL      Column02 = Command
     C                   EVAL      pcSpcBefore = DoubleSpace
     C                   EXSR      Write
     C
     C                   ENDDO
     C
     C                   EXSR      Exit
      ***************************************************************
     C     Write         BEGSR
     C
     C                   IF        pcSpacing = *blanks
     C                   EVAL      pcSpcBefore = '001'
     C                   ENDIF
     C
     C                   WRITE     QSYSPRT       PrintLine
     C                   CLEAR                   PrintLine
     C                   CLEAR                   pcSpacing
     C
     C                   ENDSR
      ***
     C***********************************************************
     C     PrintHeaders  BEGSR
     C
     C                   EVAL      PageNbr += 1
     C                   EVAL      PrintLine = 'PDM Options   '
     C                             + ActualFile
     C                   EVAL      %SUBST(PrintLine:70) = %EDITC(UDate:'Y')
     C                               + '   Page ' + %CHAR(PageNbr)
     C                   EVAL      pcSkpBefore = TopOfForm
     C                   EXSR      Write
     C
     C                   EVAL      Overflow = *OFF
     C
     C                   ENDSR
     C**************************************************************
     C     Exit          BEGSR
     C
     C                   EVAL      *INLR = *ON
     C/Exec SQL
     C+   Close Input
     C/End-exec
     C                   RETURN
     C
     C                   ENDSR
     C***********************************************************
     C     RtvOverride   BEGSR
     C
     C                   CALLP     QDMRTVFO (OutfoDS: %Len(OutfoDS):
     C                                       'OVRL0100': 'QAUOOPT':
     C                                       OutfoErrorDS)
     C                   IF        OutfoErrorDS.BytesAvail = *ZERO
     C                             AND OutfoErrorDS.ExceptionID = *blanks
     C                             AND OutfoDS.FileName <> *blanks
     C                   EVAL      ActualFile = 'File:'
     C                             + %TRIMR(OutfoDS.LibName)
     C                             + '/' + %TRIMR(OutfoDS.FileName)
     C                             + '(' + %TRIMR(OutfoDS.MemberName) + ')'
     C                   ENDIF
     C
     C                   ENDSR