API Fun Time

Published: July 16, 2008

Hey, Ted:

We have a job that is designed to run periodically to collect XML files from a third party via FTP. Rather than have a program that is constantly active, it was decided that the very first action of the program would be to re-submit itself to a single entry job queue with a scheduled run time derived from a maintainable value held on a file. The benefit of this approach is that if for some reason the program fails there is no need to worry about re-starting the process--unless of course the program failed at the self-submit stage!

When an initial start of the process is required the program can be called in "startup" mode. The routine for this first checks to make sure there isn't an instance on the job queue with a status of scheduled. If there is, a suitable message is sent. Now it would be convenient if this message included the time of the next run of the program so I turned for help to the Retrieve Job Information QUSRJOBI API.

The good news is that there is a format (JOBI0400) that provides "Date and time job is scheduled to run"; the less good news is that it is returned in a strange eight character field. In a corner of the Work Management API Attribute Descriptions manual I eventually found a clue: "The format for this field is the system time-stamp format." So how do I use it? Some determined Googling turned up the answer, call the Convert Date and Time Format (QWCCVTDT) API with an input format of *DTS (system time-stamp) and an output format of *YYMD. Below is some code to do the trick:

************************************************************
*Program to retrieve the scheduled run time of a queued job*
*Input parameter : qualified job name of scheduled job     *
*Output parameter: scheduled run time in format hh:mm:ss   *
************************************************************
D SCD001          PR                  extpgm('SCD001')
D pJob                          26
D pStime                         8

D SDX001          PI
D pJob                          26
D pStime                         8

D CvtDatTim       PR                  extpgm('QWCCVTDT')
D   pInpFmt                     10
D   pInpVal                      8
D   pOutFmt                     10
D   pOutVal                     17
D   ErrorData                32766    options(*varsize)

D RtvJobInf       PR                  extpgm('QUSRJOBI')
D   RcvVar                   32766    options(*varsize)
D   RcvVarLen                   10i 0 const
D   Format                       8    const
D   JobName                     26    const
D   IntJobID                    16    const
D   ErrorData                32766    options(*varsize)

 * API error data structure
D erDs            DS
D  erDsBytesP                   10i 0 inz(0)
D  erDsBytesA                   10i 0 inz(0)
D  erDsMsgID              9     15
D  erDsReserv            16     16
D  erDsMsgDta            17    256

 * Definitions for QUSRJOBI formats
 /COPY QSYSINC/QRPGLESRC,QUSRJOBI

D ScdDatTim       DS
D  ScdDat                        8s 0
D  ScdHMS                        6s 0
D  ScdMS                         3s 0

 * Convert date/time (QWCCVTDT) API input/output formats
D InpFmt          S             10    inz( '*DTS' )
D OutFmt          S             10    inz( '*YYMD' )

 * Edit word constant to format the time
D editwd          C                   '  :  :  '

* Monitor for errors eg job not found
C                   monitor

 * Retrieve job attribute information
C                   callp     RtvJobInf(QUSI0400:%size(QUSI0400):
C                                    'JOBI0400':pJob:*blank:erDs)
C                   if        erDsBytesA > 0
C                   eval      pStime     = 'unknown'
C                   else
* Convert from system timestamp to something readable!
C                   callp     CvtDatTim(InpFmt:QUSSDT:OutFmt:
C                                          ScdDatTim:erDs)
 * Return scheduled run time in the format hh:mm:ss
C                   eval      pStime     = %editw(ScdHMS:editwd 
C                   endif

C                   on-error
C                   eval      pStime     = 'unknown'
C                   endmon

C                   eval      *Inlr      = *on
C                   return

--Phil Hope

Thanks to Phil for sharing his code with the rest of us. I have fought similar battles, but never arrived at Phil's graceful solution.

--Ted

                     Post this story to del.icio.us
               Post this story to Digg
    Post this story to Slashdot