PGM        PARM(&FILE &USERID)

             DCL        VAR(&FILE) TYPE(*CHAR) LEN(20)
             DCL        VAR(&USERID) TYPE(*CHAR) LEN(10)

             DCL        VAR(&FILENAME) TYPE(*CHAR) LEN(10)
             DCL        VAR(&LIBNAME) TYPE(*CHAR) LEN(10)

             DCL        VAR(&COMMAND) TYPE(*CHAR) LEN(10) VALUE('TEST')
             DCL        VAR(&KEYWORD) TYPE(*CHAR) LEN(10)
             DCL        VAR(&VALID) TYPE(*LGL)
             DCL        VAR(&VALUE) TYPE(*CHAR) LEN(32)

             DCL        VAR(&ERRMSG) TYPE(*CHAR) LEN(512)
             DCL        VAR(&ERRMSGHDR) TYPE(*CHAR) LEN(4) VALUE('0000')


/*================================================================================================*/
/* Check to see if File exists                                                                    */
/*================================================================================================*/
             CHGVAR     VAR(&FILENAME) VALUE(%SST(&FILE 1 10))
             CHGVAR     VAR(&LIBNAME) VALUE(%SST(&FILE 11 10))

             CHKOBJ     OBJ(&LIBNAME/&FILENAME) OBJTYPE(*FILE)
             MONMSG     MSGID(CPF9800) EXEC(DO)
             CHGVAR     VAR(&ERRMSG) VALUE(&ERRMSGHDR *TCAT 'File +
                          not found')
             GOTO       CMDLBL(SNDERRMSG)
             ENDDO


/*================================================================================================*/
/* Check to see if UserID Parm is Valid                                                           */
/*================================================================================================*/
             CHGVAR     VAR(&KEYWORD) VALUE('USERID')
             CHGVAR     VAR(&VALUE) VALUE(&USERID)
             CALLPRC    PRC(#VLDCMDPARM) PARM(&COMMAND &KEYWORD &VALUE) RTNVAL(&VALID)

             IF         COND(*NOT &VALID) THEN(DO)
             CHGVAR     VAR(&ERRMSG) VALUE(&ERRMSGHDR *TCAT 'Invalid User-ID')
             GOTO       CMDLBL(SNDERRMSG)
             ENDDO


/*================================================================================================*/
/* End of Validity Checking                                                                       */
/*================================================================================================*/
             GOTO       CMDLBL(ENDPGM)


/*================================================================================================*/
/* Send Error Messages                                                                            */
/*================================================================================================*/
 SNDERRMSG:
             SNDPGMMSG  MSGID(CPD0006) MSGF(QCPFMSG) MSGDTA(&ERRMSG) MSGTYPE(*DIAG)
             SNDPGMMSG  MSGID(CPF0002) MSGF(QCPFMSG) MSGTYPE(*ESCAPE)


 ENDPGM:
             ENDPGM