OPNQRYF and Quotation Marks

Hey, Ted:

-- Nonna

You'll have to double something in your code. In your example, you surround the literal 4" with double quote marks ( " ). You need to change the one double quote mark following the number 4 to two double quote marks. Your query selection string will look like this:

ATSIN *EQ "4"""

The other way to do this is to use two single quote marks ( ' ) to delimit the literal, like this:

ATSIN *EQ ''4"''

That's single quote single quote the numeral four a double quote single quote single quote.

Here's some CL code that illustrates this concept. &DESC is the field holding the user input. &DWORK holds the user input with doubled quote marks.

    DCL        &DESC       *CHAR  LEN( 25)             
    DCL        &DWORK      *CHAR  LEN( 50)             
    DCL        &QRYSLT     *CHAR  LEN(256)             
    DCL        &DBLQUOTE   *CHAR  LEN(  1) VALUE('"')  
                                                       
    DCL        &INX        *DEC   LEN(3 0)             
    DCL        &OUTX       *DEC   LEN(3 0)             
                                                       
/* Get value of &DESC using some input method here */ 
                                                       
/* Begin routine to change a double quote to two     */
/* double quotes so OPNQRYF selects records properly */
                                                       
    CHGVAR     &INX        1                           
    CHGVAR     &OUTX       1                           
                                                       
 NextChar:
    CHGVAR     %SST(&DWORK &OUTX 1)  %SST(&DESC &INX 1)
                                                       
    IF   (%SST(&DESC &INX 1) *EQ &DBLQUOTE) DO         
       CHGVAR     &OUTX                   (&OUTX + 1)  
       CHGVAR     %SST(&DWORK &OUTX 1)    (&DBLQUOTE)  
    ENDDO                                              
                                                       
    CHGVAR     &INX       (&INX + 1)                   
    CHGVAR     &OUTX      (&OUTX + 1)                  
                                                       
    IF   (&INX *LE 25) THEN(GOTO NextChar)             
                                                       
 /* End routine to double quotation marks */           
                                                       
    CHGVAR     &QRYSLT  VALUE('PMDESC *CT' *bcat +     
                               &DblQuote *cat +        
                               &DWork *tcat +          
                               &DblQuote)              
                                             
    OPNQRYF    FILE((PARTS)) QRYSLT(&QRYSLT) 

-- Ted