*
      *  To compile:
      *
      *             CRTDSPF FILE(XXX/MULTSFL1DF) SRCFILE(XXX/QDDSSRC)
      *
      *=======================================================================
     A                                      DSPSIZ(24 80 *DS3)
     A                                      CA03
     A                                      CA12
     A*
     A          R HEADER
     A*
     A                                      OVERLAY
     A                                  1 26'Multiple Subfiles - Over/Under'
     A                                      DSPATR(HI)
     A                                  1  3'MULTSFL1'
     A                                  1 71DATE
     A                                      EDTCDE(Y)
     A                                  2 71TIME
     A*
     A          R SFL1                      SFL
     A*
     A            DBFNAM        20   O  4  5
     A            DBMINI         1   O  4 31
     A            DBLNAM        20   O  4 37
     A*
     A*
     A          R SF1CTL                    SFLCTL(SFL1)
     A                                      SFLSIZ(0050)
     A                                      SFLPAG(0007)
     A                                      OVERLAY
     A  32                                  SFLDSP
     A                                      SFLDSPCTL
     A  31                                  SFLCLR
     A  90                                  SFLEND(*MORE)
     A            CURSOR         1   I  3  2DSPATR(ND)
     A                                  3  5'First Name'
     A                                      DSPATR(HI)
     A                                  3 30'MI'
     A                                      DSPATR(HI)
     A                                  3 37'Last Name'
     A                                      DSPATR(HI)
     A            RRN1           4S 0H      SFLRCDNBR
     A*
     A          R SFL2                      SFL
     A*
     A            DBFNAM        20   O 14  5
     A            DBMINI         1   O 14 31
     A            DBLNAM        20   O 14 37
     A*
     A*
     A          R SF2CTL                    SFLCTL(SFL2)
     A*  
     A                                      SFLSIZ(0050)
     A                                      SFLPAG(0007)
     A                                      OVERLAY
     A  42                                  SFLDSP
     A                                      SFLDSPCTL
     A  41                                  SFLCLR
     A  90                                  SFLEND(*MORE)
     A            CURSOR         1   I 13  2DSPATR(ND)
     A                                 13  5'First Name'
     A                                      DSPATR(HI)
     A                                 13 30'MI'
     A                                      DSPATR(HI)
     A                                 13 37'Last Name'
     A                                      DSPATR(HI)
     A            RRN2           4S 0H      SFLRCDNBR
     A          R FOOTER
     A*
     A                                      OVERLAY
     A                                 22  3'F3=Exit'
     A                                      COLOR(BLU)
     A                                    +3'F12=Cancel'
     A                                      COLOR(BLU)