A*
     A*
     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT
     A                                      ERRSFL
     A                                      CA03
     A                                      CA12
     A*
     A          R SFL1                      SFL
     A*
     A  74                                  SFLNXTCHG
     A            DBIDNM    R        H      REFFLD(PFR/DBIDNM *LIBL/SFL001PF)
     A            OPTION         1A  B 10  3VALUES(' ' '2' '4' '5')
     A            DBLNAM    R        O 10  7REFFLD(PFR/DBLNAM *LIBL/SFL001PF)
     A            DBFNAM    R        O 10 31REFFLD(PFR/DBFNAM *LIBL/SFL001PF)
     A            DBMINI    R        O 10 55REFFLD(PFR/DBMINI *LIBL/SFL001PF)
     A            DBNNAM    R        O 10 60REFFLD(PFR/DBNNAM *LIBL/SFL001PF)
     A          R SF1CTL                    SFLCTL(SFL1)
     A*
     A                                      CF06
     A                                      SFLSIZ(0013)
     A                                      SFLPAG(0012)
     A                                      ROLLUP
     A                                      OVERLAY
     A N32                                  SFLDSP
     A N31                                  SFLDSPCTL
     A  31                                  SFLCLR
     A  90                                  SFLEND(*MORE)
     A            RRN1           4S 0H      SFLRCDNBR
     A                                  9  7'Last Name'
     A                                      DSPATR(HI)
     A                                  9 31'First Name'
     A                                      DSPATR(HI)
     A                                  9 55'MI'
     A                                      DSPATR(HI)
     A                                  9 60'Nick Name'
     A                                      DSPATR(HI)
     A                                  1  2'SFLMNT'
     A                                  1 71DATE
     A                                      EDTCDE(Y)
     A                                  2 71TIME
     A                                  1 24'Subfile Program with Update     '
     A                                      DSPATR(HI)
     A                                  4  2'Position to Last Name . . .'
     A            PTNAME        20A  B  4 30
     A                                  9  2'Opt'
     A                                      DSPATR(HI)
     A                                  6  2'Type options, press Enter.'
     A                                      COLOR(BLU)
     A                                  7  4'2=Change'
     A                                      COLOR(BLU)
     A                                  7 19'4=Delete'
     A                                      COLOR(BLU)
     A                                  7 34'5=Display'
     A                                      COLOR(BLU)
     A*
     A          R PANEL1
     A                                  1  2'SFLMNT'
     A            MODE           6   O  2  2DSPATR(HI)
     A                                  1 24'Subfile Program with Update     '
     A                                      DSPATR(HI)
     A                                  1 71DATE
     A                                      EDTCDE(Y)
     A                                  2 71TIME
     A            DBIDNM    R        O  4 23REFFLD(PFR/DBIDNM *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBFNAM    R        B  6 23REFFLD(PFR/DBFNAM *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBLNAM    R        B  8 23REFFLD(PFR/DBLNAM *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBMINI    R        B 10 23REFFLD(PFR/DBMINI *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBNNAM    R        B 12 23REFFLD(PFR/DBNNAM *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBADD1    R        B 14 23REFFLD(PFR/DBADD1 *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBADD2    R        B 16 23REFFLD(PFR/DBADD2 *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBADD3    R        B 18 23REFFLD(PFR/DBADD3 *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                 23 12'F12=Cancel'
     A                                      COLOR(BLU)
     A                                  4  3'Customer Number . :'
     A                                  6  3'First Name. . . . .'
     A                                  8  3'Last Name . . . . .'
     A                                 10  3'Middle Initial. . .'
     A                                 12  3'Nick Name . . . . .'
     A                                 14  3'Address Line 1. . .'
     A                                 16  3'Address Line 2. . .'
     A                                 18  3'Address Line 3. . .'
     A          R PANEL2
     A*
     A                                  1  2'SFLMNT'
     A            MODE           6   O  2  2DSPATR(HI)
     A                                  1 24'Subfile Program with Update     '
     A                                      DSPATR(HI)
     A                                  1 71DATE
     A                                      EDTCDE(Y)
     A                                  2 71TIME
     A            DBIDNM    R        O  4 20REFFLD(PFR/DBIDNM *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBFNAM    R        O  6 20REFFLD(PFR/DBFNAM *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBLNAM    R        O  8 20REFFLD(PFR/DBLNAM *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBMINI    R        O 10 20REFFLD(PFR/DBMINI *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBNNAM    R        O 12 20REFFLD(PFR/DBNNAM *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBADD1    R        O 14 20REFFLD(PFR/DBADD1 *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBADD2    R        O 16 20REFFLD(PFR/DBADD2 *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A            DBADD3    R        O 18 20REFFLD(PFR/DBADD3 *LIBL/SFL001PF)
     A                                      DSPATR(HI)
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                 23 12'F12=Cancel'
     A                                      COLOR(BLU)
     A                                  4  3'Customer Number:'
     A                                  6  3'First Name . . :'
     A                                  8  3'Last Name. . . :'
     A                                 10  3'Middle Initial :'
     A                                 12  3'Nick Name. . . :'
     A                                 14  3'Address Line 1 :'
     A                                 16  3'Address Line 2 :'
     A                                 18  3'Address Line 3 :'
     A*
     A          R SFL2                      SFL
     A*
     A            DBIDNM    R        H      REFFLD(PFR/DBIDNM *LIBL/SFL001PF)
     A            DBLNAM    R        O  7  3REFFLD(PFR/DBLNAM *LIBL/SFL001PF)
     A            DBFNAM    R        O  7 29REFFLD(PFR/DBFNAM *LIBL/SFL001PF)
     A*
     A*
     A          R SF2CTL                    SFLCTL(SFL2)
     A*
     A                                      SFLSIZ(0016)
     A                                      SFLPAG(0015)
     A                                      SFLDSP
     A  41                                  SFLCLR
     A N41                                  SFLDSPCTL
     A N41                                  SFLEND(*MORE)
     A                                      OVERLAY
     A            RRN2           4S 0H
     A                                  3  3'Press Enter to confirm your choice-
     A                                      s for Delete.'
     A                                      COLOR(BLU)
     A                                  4  3'Press F12=Cancel to return to chan-
     A                                      ge your choices.'
     A                                      COLOR(BLU)
     A                                  6  3'Last Name'
     A                                      DSPATR(HI)
     A                                  6 29'First Name'
     A                                      DSPATR(HI)
     A                                  1 28'Confirm Delete of Records'
     A                                      DSPATR(HI)
     A*
     A          R FKEY1
     A*
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                    +3'F6=Add'
     A                                      COLOR(BLU)
     A                                    +3'F12=Cancel'
     A                                      COLOR(BLU)
     A*
     A          R FKEY2
     A*
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                    +3'F12=Cancel'
     A                                      COLOR(BLU)
     A          R FKEY3
     A*
     A                                 23  2'F12=Cancel'
     A                                      COLOR(BLU)