A*=======================================================================
     A*
     A*  To compile:
     A*
     A*             CRTDSPF FILE(XXX/DTAENTDF) SRCFILE(XXX/QDDSSRC)
     A*
     A*=======================================================================
     A*
     A*%%EC
     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT
     A                                      ERRSFL
     A                                      CA03
     A                                      CA12
     A*
     A          R SFL1                      SFL
     A*
     A            DBLNAM    R        B  5  2REFFLD(PFR/DBLNAM *LIBL/SFL001PF)
     A                                      SFLCSRPRG
     A                                      CHECK(LC)
     A            DBFNAM    R        B  5 26REFFLD(PFR/DBFNAM *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBMINI    R        B  5 50REFFLD(PFR/DBMINI *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBNNAM    R        B  5 55REFFLD(PFR/DBNNAM *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A*
     A*
     A          R SF1CTL                    SFLCTL(SFL1)
     A*%%TS  SD  19991208  143614  I013KMV     REL-V4R2M0  5769-PW1
     A                                      SFLSIZ(0050)
     A                                      SFLPAG(0017)
     A                                      OVERLAY
     A N32                                  SFLDSP
     A N31                                  SFLDSPCTL
     A  31                                  SFLINZ
     A                                      SFLRNA
     A  90                                  SFLEND(*MORE)
     A                                  1  2'DTAENTRG'
     A                                  1 25'Add Data to Blank Subfile Lines'
     A                                      DSPATR(HI)
     A                                  1 71DATE
     A                                      EDTCDE(Y)
     A                                  2 71TIME
     A                                  4  2'Last Name'
     A                                      DSPATR(HI)
     A                                  4 26'First Name'
     A                                      DSPATR(HI)
     A                                  4 50'MI'
     A                                      DSPATR(HI)
     A                                  4 55'Nick Name'
     A                                      DSPATR(HI)
     A*
     A          R FKEY1
     A*
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                 23 12'F12=Cancel'
     A                                      COLOR(BLU)