*=======================================================================
      *
      *  To compile:
      *
      *             CRTDSPF FILE(XXX/DTAUPDDF) SRCFILE(XXX/QDDSSRC)
      *
      *=======================================================================
     A*
     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT
     A                                      ERRSFL
     A                                      CA03
     A                                      CA12
     A*
     A          R SFL1                      SFL
     A*
     A            DBIDNM    R        H      REFFLD(PFR/DBIDNM *LIBL/SFL001PF)
     A            DBLNAM    R        B  5  2REFFLD(PFR/DBLNAM *LIBL/SFL001PF)
     A                                      SFLCSRPRG
     A                                      CHECK(LC)
     A            DBFNAM    R        B  5 26REFFLD(PFR/DBFNAM *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBMINI    R        B  5 50REFFLD(PFR/DBMINI *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A            DBNNAM    R        B  5 55REFFLD(PFR/DBNNAM *LIBL/SFL001PF)
     A                                      CHECK(LC)
     A*
     A          R SF1CTL                    SFLCTL(SFL1)
     A*
     A                                      SFLSIZ(0050)
     A                                      SFLPAG(0017)
     A                                      OVERLAY
     A N32                                  SFLDSP
     A N31                                  SFLDSPCTL
     A  31                                  SFLINZ
     A                                      SFLRNA
     A  90                                  SFLEND(*MORE)
     A            RRN1           4S 0H      SFLRCDNBR(CURSOR)
     A                                  4  2'Last Name'
     A                                      DSPATR(HI)
     A                                  4 26'First Name'
     A                                      DSPATR(HI)
     A                                  4 50'MI'
     A                                      DSPATR(HI)
     A                                  4 55'Nick Name'
     A                                      DSPATR(HI)
     A                                  1  2'DTAUPDRG'
     A                                  1 27'Simple Subfile Program'
     A                                      DSPATR(HI)
     A                                  1 71DATE
     A                                      EDTCDE(Y)
     A                                  2 71TIME
     A*
     A          R FKEY1
     A*
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                 23 12'F12=Cancel'
     A                                      COLOR(BLU)