Scheduling a Job to Run More than Once a Day

Hey, Ted:

How can I schedule a job to run more than once a day? The Add Job Schedule Entry (ADDJOBSCDE) command has only the frequency options of *monthly, *weekly, *once.

-- Rocky

One option is to install IBM's licensed program product 5722-JS1 (Job Scheduler for iSeries) and use the Add Job using Job Scheduler (ADDJOBJS) command. If I am not mistaken, IBM charges extra for this job scheduler.

If you want to use ADDJOBSCDE instead, write a CL program to schedule the jobs throughout the day. Let the job scheduler execute your CL program.

For example, assume you want to run a job on the hour from 7:00 AM to 5:00 PM (0700 to 1700 hours), Monday through Friday. Your CL program, which I'll call SKEDPGM, looks something like this:

PGM                                                   
                                                      
   DCL &SKEDTIME     *CHAR 4                          
   DCL &TIME         *DEC  4                          
   DCL &BEGTIME      *DEC  4  VALUE(0700)             
   DCL &ENDTIME      *DEC  4  VALUE(1700)             
   DCL &INCREMENT    *DEC  4  VALUE(0100)             
                                                      
   MONMSG CPF0000 EXEC(GOTO ERROR)                    
                                                      
   CHGVAR &TIME &BEGTIME                              
NEXTSKED:                                             
   CHGVAR &SKEDTIME &TIME                             
   SBMJOB     CMD(CALL SOMEPGM) + 
                JOB(SOMEJOB) +                      
                SCDTIME(&SKEDTIME)                    
   IF (&TIME *LT &ENDTIME) DO                         
      CHGVAR &TIME (&TIME + &INCREMENT)               
      GOTO NEXTSKED  
   ENDDO             
   RETURN            
                     
ERROR:               
   /* DO WHATEVER */ 
                     
ENDPGM               

Notice the SCDTIME parameter on the Submit Job (SBMJOB) command. This schedules the job to run at a later time.

Notice also that the expression that increments the &TIME variable is decimal arithmetic, not time arithmetic. If you are scheduling a job to run every ten minutes, for example, you will have to increment the hour and reset minutes to zero when minutes reaches a value of 60.

Have the job scheduler run this program before 7:00 AM:

ADDJOBSCDE JOB(MYJOB) +
           CMD(CALL PGM(SKEDPGM)) +
           FRQ(*WEEKLY) +
           SCDDATE(*NONE) +
           SCDDAY(*MON *TUE *WED *THU *FRI) +
           SCDTIME(003000)

-- Ted

Sponsored By TRAMENCO

Introducing a New Source for Training and Mentoring. Follow this link to a vital new source for how-to technical information: www.tramenco.com. Unlike companies that offer training as an afterthought, The Training and Mentoring Company (Tramenco) is dedicated to just one thing: Advancing your career by giving you the skills you need to solve real-world business problems. You get the best information from the world's leading experts--Howard Arner, Kelly Conklin, Don Denoncourt, Susan Gantner, Skip Marchesani, Glen Marchesani, Shannon O'Donnell, Craig Pelke, and Richard Shaler. Choose from a menu of training options to fit your needs: onsite seminars, public seminars, mentoring, consulting, books, CBTs, and Web-based training. And make plans to attend the 2002 iSeries Connection Conference, the multi-day, multi-track conference that was the only sold-out iSeries training event this year, co-sponsored by the Education Connection and Tramenco. For more information about Tramenco's career enhancing opportunities, call (800) 421-8031 or go to www.tramenco.com.