Find the Cursor Position in a CL Program

Hey, Howard:

At my shop, we have field on-line help in our RPG programs that allows the user to place the cursor on a field, then press F1 and get help for that field. The RPG passes row and column data to the help text program to accomplish this. Is there way to capture row and column in a CL program to accomplish the same thing? Currently, we get a help text-screen that covers the entire screen, not just the field that the cursor is on.

-- Larry

My friend Holley Davis can help you with this one, Larry. Here's his solution.

-- Howard

The cursor location you are getting from your RPG programs comes from the file information data structure (INFDS) for the display file in the Display Specific Feedback Information area. This information is not available to a CL program.

However, there are two ways to tell where the cursor is in a CL program. One is based on row and column, the other on field name. The field-name method is preferable because system maintenance is easier. That is, if you move a field, the help information doesn't have to be adjusted. I will cover the field-name method now and show you the row/column method in an upcoming issue of Midrange Guru.

Add the RTNCSRLOC keyword to your display file as shown in the example below:

A*      TEST5DSPF - Test display file to demonstrate how to use
A*                  the RTNCSRLOC keyword to determine where the
A*                  the cursor is on the screen in a program.
A*                                                               
A                                      DSPSIZ(24 80 *DS3 -
A                                             27 132 *DS4)
A                                      PRINT
A* Screen format 
A* 
A*  The RTNCSRLOC uses three variables to relay information      
A*  from the display file to the program about the current       
A*  position of the cursor.                                      
A*       Record Format Name                                      
A*       Field Name                                              
A*       Position of the cursor in the field.                    
A*                                                               
A          R RCD01                                               
A                                      CF03(03)                  
A                                      RTNCSRLOC(&CSRRCD &CSRFLD &CSRPOS)
A            CSRRCD        10A  H                                        
A            CSRFLD        10A  H                                        
A            CSRPOS         4S 0H                                        
A                                  1  2'TESTPGM'                         
A            TITL1         30A  O  1 27                                  
A                                  1 72DATE                              
A                                      EDTCDE(Y)                         
A                                  4  3'Put the cursor in a field and'   
A                                      COLOR(BLU)                        
A                                  4 33'press Enter.'                    
A                                      COLOR(BLU)                        
A                                  6  3'Field One . . . . . . :'         
A            FIELD1        10A  B  6 27                                  
A                                  7  3'Field Two . . . . . . :'         
A            FIELD2         5S 0B  7 27                                  
A                                  8  3'Field Three . . . . . :'         
A            FIELD3        10A  B  8 27                                  
A            RETURN        70A  O 10  2          
A                                 23  2'F3=Exit' 
A                                      COLOR(BLU)

The RTNCSRLOC uses three variables to relay information from the display file to the program regarding the current position of the cursor. These variables return the record format name in which the cursor is located, the field name in which the cursor is located, and the position of the cursor in the field.

Use the following CL program to test this display file technique for yourself:

   /* Test program to demonstrate how to use RTNCSRLOC to locate        */  
   /* where the cursor is on the screen.                                */  
                                                                            
             PGM                                                            
                                                                            
             DCL        VAR(&POS) TYPE(*CHAR) LEN(4)                        
             DCLF       FILE(TEST5DSPF)                                     
                                                                            
   /* Send screen to display and wait for user to press something.      */  
LOOP:       SNDRCVF                                                        
                                                                            
   /* End program if F3 pressed.                                        */  
             IF         COND(&IN03) THEN(GOTO CMDLBL(END))                  
                                                                            
   /* Convert the numeric Position return to Alpha for display.         */  
             CHGVAR     VAR(&POS) VALUE(&CSRPOS)                            
                                                                            
   /* Report where the cursor is located.                               */  
             CHGVAR     VAR(&RETURN) VALUE('The cursor is in +              
                          Format -' *cat &CSRRCD *bcat ', Field -' *cat +   
                          &CSRFLD *BCAT 'at Pos-' *cat &POS)                
                                                                            
             GOTO       CMDLBL(LOOP)                                        
                                                                            
 END:        ENDPGM                                                         

I hope this helps.  

-- Holley Davis
Davis Software Services, Inc.
www.fad400.com
888-288-6676

Sponsored By COMMON

COMMON IT EXECUTIVE CONFERENCE Tell your IT Directors about the three-day event that is specially designed for them. Held October 13-15, 2002, in Denver, the IT Executive Conference will give iSeries Directors the opportunity to network and learn from well-known speakers in the iSeries environment, and receive new strategies for optimizing operations. To find out more, go to: http://www.common.org/executive