Easy Printing From CL

CL cannot write to printer files. This is understandable, since CL fits into the category of job control languages. Even though I’d never use CL to build an aged receivables report, there are times when it is advantageous for a CL program to generate a report (i.e., produce a spooled file), and here are two fairly easy ways to do that.

Suppose you have a CL program that runs three RPG programs in nightly batch processing. There are people in your organization who need to know whether these programs ran successfully or not. If you could build a short spooled file with that information, you could route that spooled file to an output queue that is monitored by third-party software, which in turn can email the report in PDF format.

First, create a printer file with the proper settings.

CRTPRTF    FILE(MYLIB/STATUSPRTF) +
   TEXT('Nightly production status report') +
   OUTQ(EMAILOUTQ)

Here are two ways to build the spooled file.

Method 1: Qshell and Rfile

Make the CL program build a Qshell command that uses the Rfile utility to write to the printer file.

pgm parm(&RunDate)

   dcl &RunDate      *char     8   /* YYYYMMDD */
   dcl &Status       *char

   dcl &EOL          *char     2   x'0d25'
   dcl &Cmd          *char   256

   chgvar &Cmd ('echo ''')

   call   QDP007101R  (&RunDate &Status)
   chgvar &Cmd (&Cmd *tcat 'Widgets   =' *cat &Status *cat &EOL)

   call   QDP007102R  (&RunDate &Status)
   chgvar &Cmd (&Cmd *tcat 'Thingies  =' *cat &Status *cat &EOL)

   call   QDP007103R  (&RunDate &Status)
   chgvar &Cmd (&Cmd *tcat 'Dohickeys =' *cat &Status *cat &EOL)

   chgvar &Cmd (&Cmd *tcat ''' | rfile -wQ mylib/StatusPrtf')

   qsh    cmd(&Cmd)
   
endpgm

The &Cmd variable will have a value like this (except that I have put two question marks where the carriage return and line feed characters go):

echo 'Widgets   =OK??Thingies  =OK??Dohickeys =FAIL??' | rfile -wQ mylib/StatusPrtf

The echo command writes text to the standard output stream. Standard output is piped into the Rfile utility. That is to say, the output from the echo is the input to Rfile. Rfile writes the streamed data to the printer file that we created. Voilà! Several cell phones display the following:

Widgets   =OK  
Thingies  =OK  
Dohickeys =FAIL

Method 2: Native files and RUNSQL

With the exception of the RUNSQL command, this method uses features that have been around since day 1.

pgm parm(&RunDate)

   dcl &RunDate      *char     8   /* YYYYMMDD */
   dcl &Status       *char

   dcl &PrintLine    *char    24
   dcl &Cmd          *char   256
   dcl &Quote        *char     1  value('''')

   clrpfm qtemp/StatusRpt
   monmsg cpf3142 exec(do)
      crtpf qtemp/StatusRpt rcdlen(24)
   enddo

   call   QDP007101R (&RunDate &Status)
   chgvar &PrintLine ('Widgets   =' *cat &Status)
   callsubr  WriteStat

   call   QDP007102R  (&RunDate &Status)
   chgvar &PrintLine ('Thingies  =' *cat &Status)
   callsubr  WriteStat

   call   QDP007103R  (&RunDate &Status)
   chgvar &PrintLine ('Dohickeys =' *cat &Status)
   callsubr  WriteStat

   cpyf   qtemp/statusrpt  StatusPrtf  fmtopt(*nochk)

   return

subr WriteStat

   chgvar &Cmd ('insert into qtemp/StatusRpt values(' *cat +
                &Quote *cat &PrintLine *tcat &Quote *cat ')')
   runsql sql(&Cmd) commit(*none)

endsubr

endpgm

This routine begins by clearing program-described work file StatusRpt if it exists and creating it otherwise. After each program call, the WriteStat subroutine writes a record to the work file. The Copy File (CPYF) command copies the work file to the printer file, producing the report.

Where there’s a will, there’s a way.