|
Simplify Complex Conditions
Hey, Ted:
One of the features I like about Open Query File is the %VALUES function, which allows me to determine whether a value is found in a list of other values. For example, the expression CTYPE = %VALUES(45 56) is equivalent to CTYPE = 45 or CTYPE = 56. RPG does not have a similar function. Is there no way to simplify complex conditions?
--David
For record selection with SQL, you can use an IN predicate with a set. However, that's not what you're asking for in this case.
One of the nice things about ILE is that you can create your own functions to do all sorts of wild and wonderful things. Here's how to create an EqAnyNum (equals any number) function that will compare a base value to any of two to eight values.
Create a source member with the following prototype. (I assume you'll use source member EQANYNUM in file COPYSRC.)
D EqAnyNum pr n
D BaseVal 10i 0 value
D Val01 10i 0 value
D Val02 10i 0 value
D Val03 10i 0 value options(*nopass)
D Val04 10i 0 value options(*nopass)
D Val05 10i 0 value options(*nopass)
D Val06 10i 0 value options(*nopass)
D Val07 10i 0 value options(*nopass)
D Val08 10i 0 value options(*nopass)
Create another source member with the following subprocedure definition. (I assume you'll use source member EQANYNUM in QRPGLESRC.)
H nomain
D/copy copysrc,eqanynum
P EqAnyNum b export
D pi n
D BaseVal 10i 0 value
D Val01 10i 0 value
D Val02 10i 0 value
D Val03 10i 0 value options(*nopass)
D Val04 10i 0 value options(*nopass)
D Val05 10i 0 value options(*nopass)
D Val06 10i 0 value options(*nopass)
D Val07 10i 0 value options(*nopass)
D Val08 10i 0 value options(*nopass)
C if %parms >= 2
C if BaseVal = Val01
C return *on
C endif
C endif
C
C if %parms >= 3
C if BaseVal = Val02
C return *on
C endif
C endif
C
C if %parms >= 4
C if BaseVal = Val03
C return *on
C endif
C endif
C
C if %parms >= 5
C if BaseVal = Val04
C return *on
C endif
C endif
C
C if %parms >= 6
C if BaseVal = Val05
C return *on
C endif
C endif
C
C if %parms >= 7
C if BaseVal = Val06
C return *on
C endif
C endif
C
C if %parms >= 8
C if BaseVal = Val07
C return *on
C endif
C endif
C
C if %parms >= 9
C if BaseVal = Val08
C return *on
C endif
C endif
C
C return *off
C
P e
Here's an example that shows how to call the function. If TRCODE has any of the five values listed in the second through sixth parameters, variable FOUND will be set to the value T; otherwise FOUND will be set to F.
D TrCode s 2s 0
D Found s 1a
D/copy copysrc,eqanynum
C if EqAnyNum (TrCode: 1:5:7:8:12)
C eval Found = 'T'
C else
C eval Found = 'F'
C endif
C eval *inlr = *on
There are several ways to bind the two modules into a program. The easiest is to use the Create RPG Module (CRTRPGMOD) command to make modules of each source member, and combine the two modules into a program using the Create Program (Create Program) command. If desired, create a service program from the module. You may also want to add the module or service program to a binding directory.
I will leave it to the interested reader to expand the EqAnyNum function to allow more than eight comparison values.
--Ted
|
WORKSRIGHT SOFTWARE
