• The Four Hundred
  • Subscribe
  • Media Kit
  • Contributors
  • About Us
  • Contact
Menu
  • The Four Hundred
  • Subscribe
  • Media Kit
  • Contributors
  • About Us
  • Contact
  • Simplify Complex Conditions

    January 28, 2004 Hey, Ted

    One of the features I like about Open Query File is the %VALUES function, which allows me to determine whether a value is found in a list of other values. For example, the expression CTYPE = %VALUES(45 56) is equivalent to CTYPE = 45 or CTYPE = 56. RPG does not have a similar function. Is there no way to simplify complex conditions?

    –David

    For record selection with SQL, you can use an IN predicate with a set. However, that’s not what you’re asking for in this case.

    One of the nice things about ILE is that you can create your own functions to do all sorts of wild and wonderful things. Here’s how to create an EqAnyNum (equals any number) function that will compare a base value to any of two to eight values.

    Create a source member with the following prototype. (I assume you’ll use source member EQANYNUM in file COPYSRC.)

    D EqAnyNum        pr              n                         
    D  BaseVal                      10i 0 value                 
    D  Val01                        10i 0 value                 
    D  Val02                        10i 0 value                 
    D  Val03                        10i 0 value options(*nopass)
    D  Val04                        10i 0 value options(*nopass)
    D  Val05                        10i 0 value options(*nopass)
    D  Val06                        10i 0 value options(*nopass)
    D  Val07                        10i 0 value options(*nopass)
    D  Val08                        10i 0 value options(*nopass)
    

    Create another source member with the following subprocedure definition. (I assume you’ll use source member EQANYNUM in QRPGLESRC.)

    H nomain
    
    D/copy copysrc,eqanynum
    
    P EqAnyNum        b                   export
    
    D                 pi              n
    D  BaseVal                      10i 0 value
    D  Val01                        10i 0 value
    D  Val02                        10i 0 value
    D  Val03                        10i 0 value options(*nopass)
    D  Val04                        10i 0 value options(*nopass)
    D  Val05                        10i 0 value options(*nopass)
    D  Val06                        10i 0 value options(*nopass)
    D  Val07                        10i 0 value options(*nopass)
    D  Val08                        10i 0 value options(*nopass)
    
    C                   if        %parms >= 2
    C                   if        BaseVal = Val01
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   if        %parms >= 3
    C                   if        BaseVal = Val02
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   if        %parms >= 4
    C                   if        BaseVal = Val03
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   if        %parms >= 5
    C                   if        BaseVal = Val04
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   if        %parms >= 6
    C                   if        BaseVal = Val05
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   if        %parms >= 7
    C                   if        BaseVal = Val06
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   if        %parms >= 8
    C                   if        BaseVal = Val07
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   if        %parms >= 9
    C                   if        BaseVal = Val08
    C                   return    *on
    C                   endif
    C                   endif
    C
    C                   return    *off
    C
    P                 e
    

    Here’s an example that shows how to call the function. If TRCODE has any of the five values listed in the second through sixth parameters, variable FOUND will be set to the value T; otherwise FOUND will be set to F.

    D TrCode          s              2s 0
    D Found           s              1a
    
    D/copy copysrc,eqanynum
    
    C                   if        EqAnyNum (TrCode: 1:5:7:8:12)
    C                   eval      Found = 'T'
    C                   else
    C                   eval      Found = 'F'
    C                   endif
    
    C                   eval      *inlr = *on
    

    There are several ways to bind the two modules into a program. The easiest is to use the Create RPG Module (CRTRPGMOD) command to make modules of each source member, and combine the two modules into a program using the Create Program (Create Program) command. If desired, create a service program from the module. You may also want to add the module or service program to a binding directory.

    I will leave it to the interested reader to expand the EqAnyNum function to allow more than eight comparison values.

    –Ted

    Share this:

    • Reddit
    • Facebook
    • LinkedIn
    • Twitter
    • Email

    Tags:

    Sponsored by
    Manta Technologies

    The Leader in IBM i Education!
    Need training on anything i?
    Manta is all you need.

    130 courses and competency exams on:
    · IBM i operations
    · System Management and Security
    · IBM i Programming Tools
    · Programming in RPG, COBOL, CL, Java
    · Web Development

    SQL, DB2, QueryProduct features:
    · Runs in every popular browser
    · Available 24/7/365
    · Free Student Reference Guides
    · Free Student Administration
    · Concurrent User License
    · Built-In IBM i Simulator

    You can download our 200-page catalog and take sample sessions at MantaTech.com

    Share this:

    • Reddit
    • Facebook
    • LinkedIn
    • Twitter
    • Email

    Bsafe Bolsters OS/400 Security Software with New Logging, Alerts New Domino and Blue Domino: A Little of Both At Lotusphere

    Leave a Reply Cancel reply

Volume 4, Number 2 -- January 28, 2004
THIS ISSUE
SPONSORED BY:

T.L. Ashford
Profound Logic Software
WorksRight Software
Twin Data
SuSE Linux

Table of Contents

  • Application and Data Integration Between Linux and OS/400
  • To Commit or Not to Commit?
  • Simplify Complex Conditions
  • Retrieve the System Name
  • OS/400 Alert: Trials and Betas

Content archive

  • The Four Hundred
  • Four Hundred Stuff
  • Four Hundred Guru

Recent Posts

  • With Power11, Power Systems “Go To Eleven”
  • With Subscription Price, IBM i P20 And P30 Tiers Get Bigger Bundles
  • Izzi Buys CNX, Eyes Valence Port To System Z
  • IBM i Shops “Attacking” Security Concerns, Study Shows
  • IBM i PTF Guide, Volume 27, Number 26
  • Liam Allan Shares What’s Coming Next With Code For IBM i
  • From Stable To Scalable: Visual LANSA 16 Powers IBM i Growth – Launching July 8
  • VS Code Will Be The Heart Of The Modern IBM i Platform
  • The AS/400: A 37-Year-Old Dog That Loves To Learn New Tricks
  • IBM i PTF Guide, Volume 27, Number 25

Subscribe

To get news from IT Jungle sent to your inbox every week, subscribe to our newsletter.

Pages

  • About Us
  • Contact
  • Contributors
  • Four Hundred Monitor
  • IBM i PTF Guide
  • Media Kit
  • Subscribe

Search

Copyright © 2025 IT Jungle