• The Four Hundred
  • Subscribe
  • Media Kit
  • Contributors
  • About Us
  • Contact
Menu
  • The Four Hundred
  • Subscribe
  • Media Kit
  • Contributors
  • About Us
  • Contact
  • Programming with Assertions

    April 21, 2004 Cletus the Codeslinger

    I am amazed to see how much programmers take for granted. For example, I have worked on many programs in which the author had assumed that an RPG CHAIN operation (a random read) would always find the sought-for record. Occasionally I have to fix a program that ended abnormally because it attempted to divide by zero. The authors of such programs assumed that the divisor would never be zero, but somehow such a thing happened.

    To help deal with the problem of assumptions, I have been using assertions in my code. An assertion is a program statement that tests an assumption and, if that assumption is not true, protests loudly. I understand that assertions come from the world of C programming.

    A typical assertion routine accepts two arguments. The first one is a condition that is always assumed to be true. The second is an error message to be sent to the user if the first argument turns out not to be as true as was previously thought. Here is an assertion routine I wrote in RPG IV.

    * ============================================================= 
     * Abruptly end the program if an unexpected condition arises.   
     * ============================================================ 
                                                                     
    P Assert          B                                              
    D Assert          PI                                             
    D   Condition                     N   Value                      
    D   Message                     80A   Value                      
                                                                     
                                                                     
    D SendEscMsg      PR                  ExtPgm('QMHSNDPM')         
    D   MsgID                        7    Const                      
    D   MsgFile                     20    Const                      
    D   MsgDta                      80    Const                      
    D   MsgDtaLen                   10I 0 Const                      
    D   MsgType                     10    Const                      
    D   MsgQ                        10    Const                      
    D   MsgQNbr                     10I 0 Const                      
    D   MsgKey                       4                               
    D   ErrorDS                     16                               
                                                                     
    D ErrorDS         DS            16                               
    D   BytesProv                   10I 0 inz(16)                    
    D   BytesAvail                  10I 0                          
    D   ExceptionID                  7                             
                                                                   
    D MsgDta          S             80                             
    D MsgKey          S              4                             
                                                                   
     /FREE                                                         
                                                                   
                                                                   
         IF (not Condition);                                       
            *inlr = *on;                                           
            SendEscMsg ('CPF9898': 'QCPFMSG   QSYS':               
                        Message: %len(Message):                    
                        '*ESCAPE': '*PGMBDY': 1: MsgKey: ErrorDS); 
         ENDIF;                                                    
         RETURN;                                                   
                                                                   
     /END-FREE                                                     
                                                                   
    P Assert          E
    

    Here’s the prototype:

    D Assert          PR                        
    D  Condition                      N   Value 
    D  Message                      80A   Value
    

    Since the first parameter is passed by value, you can use any type of expression that yields a true or false value. The second parameter is also passed by value, so it can be any expression that creates a character string.

    My assert routine sends an escape message, which terminates the program immediately. You may prefer something less drastic.

    Let’s return to the assumptions I mentioned earlier. If you think a CHAIN will never fail, you might include an assertion after the CHAIN.

    /FREE
       CHAIN %KDS(CustKey) Customer;                     
       Assert (%FOUND:                                   
               'Customer ' + %CHAR(CustKey.Company) +
               '/' + %CHAR(CustKey.CustNbr) +            
               ' was not found in the Customer file');   
    /END-FREE
    

    Here is the same example using more traditional RPG coding techniques.

    CL0N01Factor1+++++Opcode&ExtFactor2+++++Result++++++Len++D+HiLoEq....
    C   CUSKEY      CHAIN     CUSTOMER                         95      
    C               CALLP     Assert                                     
    C                         (*IN95 = *OFF:                             
    C                          'Customer ' +                             
    C                             %CHAR(COMPANY) +                       
    C                             '/' +                                  
    C                             %CHAR(CUSTNBR) +                       
    C                             ' was not found in the Customer file')
    

    If you think that a field will never be zero, you might use this type of assertion.

    /FREE                                                      
        Assert (Balance <> *zero:                               
                'Balance was zero in order ' + %CHAR(OrderNo));
        Average = Sum / Balance;
    /END-FREE
    

    To force an assertion, pass the value *OFF in the first parameter. The following assertion is activated if no WHEN clause in a SELECT group proves true.

    /FREE                                         
        SELECT;                                    
          WHEN CustClass = '01';                   
          WHEN CustClass = '02';                   
          WHEN CustClass = '03';                   
          OTHER;                                   
              Assert (*OFF:                        
                      'Invalid customer class: ' + 
                      CustClass);                  
        ENDSL;                                     
    /END-FREE                                     
    

    I find assertions are more valuable during testing than in production. I may use an assertion to verify that a field is not negative, but eventually I replace the assertion with error-handling logic. However, if my error-handling logic is to cancel the program with an escape message, I keep the assertion.

    Since assertions are usually for testing only, I sometimes condition them using a compiler directive. Here the assertion is compiled only when the TESTING condition is defined.

    /FREE                                         
        SELECT;                                    
          WHEN CustClass = '01';                   
          WHEN CustClass = '02';                   
          WHEN CustClass = '03';                   
     /IF DEFINED(TESTING)                          
          OTHER;                                   
              Assert (*OFF:                        
                      'Invalid customer class: ' + 
                      CustClass);                  
     /ENDIF                                        
        ENDSL;                                     
    /END-FREE                                     
    

    There is plenty of material about programming with assertions on the Web. You can find a good article written from a Java perspective on Sun’s Web site.

    Share this:

    • Reddit
    • Facebook
    • LinkedIn
    • Twitter
    • Email

    Tags:

    Sponsored by
    VISUAL LANSA 16 WEBINAR

    Trying to balance stability and agility in your IBM i environment?

    Join this webinar and explore Visual LANSA 16 – our enhanced professional low-code platform designed to help organizations running on IBM i evolve seamlessly for what’s next.

    🎙️VISUAL LANSA 16 WEBINAR

    Break Monolithic IBM i Applications and Unlock New Value

    Explore modernization without rewriting. Decouple monolithic applications and extend their value through integration with modern services, web frameworks, and cloud technologies.

    🗓️ July 10, 2025

    ⏰ 9 AM – 10 AM CDT (4 PM to 5 PM CEST)

    See the webinar schedule in your time zone

    Register to join the webinar now

    What to Expect

    • Get to know Visual LANSA 16, its core features, latest enhancements, and use cases
    • Understand how you can transition to a MACH-aligned architecture to enable faster innovation
    • Discover native REST APIs, WebView2 support, cloud-ready Azure licensing, and more to help transform and scale your IBM i applications

    Read more about V16 here.

    Share this:

    • Reddit
    • Facebook
    • LinkedIn
    • Twitter
    • Email

    Cleo Enhances Automation with AS2 Software for OS/400 IBM Cuts iSeries Prices Ahead of Power5 Launch

    Leave a Reply Cancel reply

Content archive

  • The Four Hundred
  • Four Hundred Stuff
  • Four Hundred Guru

Recent Posts

  • With Power11, Power Systems “Go To Eleven”
  • With Subscription Price, IBM i P20 And P30 Tiers Get Bigger Bundles
  • Izzi Buys CNX, Eyes Valence Port To System Z
  • IBM i Shops “Attacking” Security Concerns, Study Shows
  • IBM i PTF Guide, Volume 27, Number 26
  • Liam Allan Shares What’s Coming Next With Code For IBM i
  • From Stable To Scalable: Visual LANSA 16 Powers IBM i Growth – Launching July 8
  • VS Code Will Be The Heart Of The Modern IBM i Platform
  • The AS/400: A 37-Year-Old Dog That Loves To Learn New Tricks
  • IBM i PTF Guide, Volume 27, Number 25

Subscribe

To get news from IT Jungle sent to your inbox every week, subscribe to our newsletter.

Pages

  • About Us
  • Contact
  • Contributors
  • Four Hundred Monitor
  • IBM i PTF Guide
  • Media Kit
  • Subscribe

Search

Copyright © 2025 IT Jungle